ECS-L Home Automation and Security Archives
  learn more | view messages for this month | NetBloc® | terms of use | search

Google
 


  subject (prev) or (next) | time (prev) or (next) | author (prev) or (next) | view more subjects

Subject:
From:
Date:		 Re: [ECS] Concealed
Mark Gilmore
Mon, 08 May 2000 12:11:42 -0400
Mon, 08 May 2000 12:11:42 -0400 
Hi Scott,
For a RADMIN connection, this is handled via macro "50"
(see ECS.HTM & ECS.CFG).
But in the NEW ECS.CFG (which ALSO uses the new "ISP" Type),
this macro is changed to "60", and "50" triggers a "ECS/WWW"
dialup.

ATTACHED are all Items/Events effected by these changes
(should you care to CAREFULLY "merge" them into your cfg).
-- 
Mark Gilmore
Omnipotence (ECS home automation software)
http://www.usit.com/omnip
423-745-0026
Hours: Mon-Sat, 9AM-8PM/EST


Scott Danks wrote:
> 
> Subject:  Re: [ECS] Modem question
> 
> Hi Mark.
> 
> I was just wondering.  I am in a place that has no DSL or Cable Modem.  I have the
Zoom 14400 modem answering the phone and taking messages.  Are there any provisions
for calling my home with my modem from work and the modem on the ECS autosensing and
letting me connect to the pc to do this web enabled control stuff?  or does it have
to be online already?

Item:ISP			Type:ISP			Acc:User/User
	Initial	State:(none)					Backup:No
	ISP address  :
;	Denotes ISP-connection status
;-------------------------------------------------------------------------------
Item:ISP Usage Count		Type:Number			Acc:User/User
	Initial State:0						Backup:No
;	Denotes number of processes currently using your ISP
;	(used to determine when we should disconnect).
;-------------------------------------------------------------------------------
Item:ISP Disconnect		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :ISPDISC.BAT
;	Command to disconnect from ISP
;-------------------------------------------------------------------------------
Item:ISP conn msg		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :ISP connected
;	Displayed when ISP connects
;	Group refs: (none)
;	Event refs: Phone Service
;-------------------------------------------------------------------------------
Item:ISP disc msg 1		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :ISP disconnected - resetting Phone-Interface-C ...
;	Displayed when ISP disconnects
;	Group refs: (none)
;	Event refs: Phone Service
;-------------------------------------------------------------------------------
Item:ISP disc msg 2		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :ISP disconnected - resetting Phone-Interface-C ... DONE
;	Displayed when ISP disconnects
;	Group refs: (none)
;	Event refs: Phone Service
;-------------------------------------------------------------------------------
Item:ECS/WWW Connect		Type:True/False			Acc:User/Owner
	Initial State:False					Backup:No
;	Set to TRUE to initiate an ECS/WWW connection (see ECS.HTM).
;-------------------------------------------------------------------------------
Item:ECS/WWW Msg		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :Connecting now - goodbye
;	Message spoken when user enters macro to connect to ISP
;-------------------------------------------------------------------------------
Item:ECS_WWW.BAT		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :ECS_WWW.BAT
;	Batch file to initiate ECS/WWW connection
;-------------------------------------------------------------------------------
Item:R_SERVER Connect		Type:True/False			Acc:User/Owner
	Initial State:False					Backup:No
;	Set to TRUE to initiate a ISP/R_SERVER connection (see ECS.HTM).
;-------------------------------------------------------------------------------
Item:R_SERVER.BAT		Type:Text			Acc:User/User
	Initial	State:(none)					Backup:No
	Text	     :R_SERVER.BAT
;	Batch file to initiate ISP/R_SERVER connection
;-------------------------------------------------------------------------------
Item:Email on call		Type:True/False			Acc:User/Owner
	Initial State:False					Backup:Yes
;	If this Item is TRUE after ECS answers the phone, the message will
;	be emailed to you as a .WAV file.
;-------------------------------------------------------------------------------
Item:Email Ack			Type:True/False			Acc:User/Owner
	Initial State:False					Backup:Yes
;	If this Item is TRUE, ECS will set emailed messages to "played" status.
;	be emailed to you as a .WAV file.
;-------------------------------------------------------------------------------
Item:LMEMAIL.BAT		Type:Text			Acc:User/Owner
	Initial State:(none)					Backup:No
	Text         :LMEMAIL.BAT
;	Batch file used to email phone messages.
;-------------------------------------------------------------------------------
Item:LMEMAIL.TMP		Type:File			Acc:User/User
	Initial	State:(none)					Backup:No
	File	     :LMEMAIL.TMP
;	File that holds status of phone-msg email.
;-------------------------------------------------------------------------------
Item:Email Status		Type:Character			Acc:User/User
	Initial	State:I						Backup:Yes
;	Denotes phone-msg email status (extracted from LMEMAIL.TMP)
;	(I=idle, A=active, D=done/OK, E/other=error)
;-------------------------------------------------------------------------------
Item:Email Error		Type:Text			Acc:User/Owner
	Initial State:(none)					Backup:No
	Text         :Email ERROR
;	Error message if email fails
;-------------------------------------------------------------------------------
Item:TVLSTAT.TMP		Type:File			Acc:User/User
	Initial	State:(none)					Backup:No
	File	     :TVLSTAT.TMP
;	File that holds status of TVL download (set in TVL.BAT)
;-------------------------------------------------------------------------------
Item:TVL DL Status		Type:Character			Acc:User/User
	Initial	State:I						Backup:Yes
;	Denotes TVL download status (extracted from TVLSTAT.TMP)
;	(I=idle, A=active, D=done/OK, E/other=error)

Event:	Phone Service			Called ?:No
	;****************************************************************
	; This Event performs various phone-related tasks:
	;----------------------------------------------------------------
	; Send remote phone keystrokes to it's session processor:
	Do	Remote Phone Sess.	Set		Remote-Phone-Button
	;----------------------------------------------------------------
	; Log CID info soon as it comes in:
	If	CID-C			Is Not Now	None
	Then	CID-C			Set		Log
	Then	Old Phone-Rings		Set		0
	;----------------------------------------------------------------
	; Display/announce the caller every time the phone rings therafter:
	If	CID-C			Is Not		None
	And	Phone-Rings		Is GT		Old Phone-Rings
	And	Phone-Answer		Is Not		Answering
	Then	CID-C			Set		Speak->VC
	Do	Old Phone-Rings		Set		Phone-Rings
	;----------------------------------------------------------------
	; 5 seconds after Phone-Rings has reverted to 0, reset CID-C to NONE:
	If	Phone-Rings		Is Now		0
	Then	CID Timer		Set		5
	If	CID Timer		Is Now		0
	Then	CID-C			Set		None
	;----------------------------------------------------------------
	; Answer phone after enough rings:
	If	Phone-Rings		Is GE		Answer Ring Count
	Then	Phone-Answer		Set		Answer
	;
	;****************************************************************
	; Handle newly recorded message:
	;----------------------------------------------------------------
	BEGINIF	Phone-Answer		Is Now		Message Recorded
	;----------------------------------------------------------------
	; Announce that we have a message and setup
	; for periodic reminder (handled below):
	Do	Phone Messages Msg	Set		Speak->VC
	Do	Phone Message Timer	Set		Reminder Frequency
	Do	New Msgs Reminder	Set		True
	;----------------------------------------------------------------
	; If desired, send message to pager denoting name/number of caller:
	If	Page on call		Is		True
	And	CID-C			Is Not		None
	Then	Text-A			T1<-T1		CID-Name
	Then	Text-A			Set		:
	Then	Text-A			T1/A<-T1	CID-Number
	Then	Text-A			Set		Send->Pager
	;----------------------------------------------------------------
	; If desired, email recording as a .WAV file attachment:
	BEGINIF	Email on call		Is		True
	If	Phone-Interface-C	Is		Operational
	Then	Phone-Interface-C	Set		Disconnected
	Then	ISP Usage Count		Set		0
	; Email the message:
	Do	LMEMAIL.TMP		Set		Delete
	Do	LMEMAIL.TMP		Set		Reset
	Do	LMEMAIL.BAT		Set		Execute/NW
	Do	ISP Usage Count		Add		1
	Do	Email Status		Set		A
	ENDIF
	;----------------------------------------------------------------
	ENDIF
	;
	;****************************************************************
	; Check email completion-status (if active)
	;----------------------------------------------------------------
	BEGINIF	Email Status		Is		A
	Do	Character-A		Set		LMEMAIL.TMP
	BEGINIF	Character-A		Is Not		None
	Do	Email Status		Set		Character-A
	Do	ISP Usage Count		Subtract	1
	If	Email Status		Is		D
	And	Email Ack		Is		True
	Then	New-Phone-Messages	Set		Acknowledge
	Else If	Email Status		Is Not		D
	Then	Email Error		Set		Log
	ENDIF
	ENDIF
	;
	;****************************************************************
	; Disconnect if all ISP tasks are complete
	;----------------------------------------------------------------
	If	ISP Usage Count		Is Now		0
	And	Phone-Interface-C	Is Not		Operational
	Then	ISP Disconnect		Set		Execute/NW
	;
	;****************************************************************
	; Monitor for ISP connect/disconnect
	;----------------------------------------------------------------
	If	ISP			Is Now		Connected
	Then	ISP conn msg		Set		Display
	Else If	ISP			Is Now		Disconnected
	Then	ISP disc msg 1		Set		Display
	Then	Pause			Set		200
	Then	Phone-Interface-C	Set		Reset
	Then	ISP Usage Count		Set		0
	Then	ISP disc msg 2		Set		Display
	;
	;****************************************************************
	; Issue periodic new-message reminder until acknowledged:
	;----------------------------------------------------------------
	BEGINIF	New Msgs Reminder	Is		True
	If	Sign Of Life		Is		True
	Or	New-Phone-Messages	Is Now		0
	Then	Phone Message Timer	Set		0
	Then	New Msgs Reminder	Set		False
	Then	Phone Messages Msg	Set		Speak->VC
	Then	Reminder Ack Msg	Set		Speak->VC
	;
	Else If	Phone Message Timer	Is		0
	Then	Phone Messages Msg	Set		Speak->VC
	Then	Phone Message Timer	Set		Reminder Frequency
	ENDIF
	End

Event:	ECS/WWW			Called ?:No
	;****************************************************************
	; Handle ECS/WWW connection (for remote access)
	;----------------------------------------------------------------
	;
	BEGINIF	ECS/WWW Connect		Is		True
	Do	ECS/WWW Connect		Set		False
	;----------------------------------------------------------------
	; Initiate ECS/WWW connection
	;----------------------------------------------------------------
	If	Phone-Interface-C	Is		Operational
	Then	Phone-Interface-C	Set		Disconnected
	Then	ISP Usage Count		Set		0
	Do	ECS_WWW.BAT		Set		Execute
	Do	ISP Usage Count		Add		1
	ENDIF
	End

Event:	R_SERVER			Called ?:No
	;****************************************************************
	; Handle ISP/R_SERVER connection (for remote access via RADMIN)
	;----------------------------------------------------------------
	;
	BEGINIF	R_SERVER Connect	Is		True
	Do	R_SERVER Connect	Set		False
	;----------------------------------------------------------------
	; Initiate ISP/R_SERVER connection
	;----------------------------------------------------------------
	If	Phone-Interface-C	Is		Operational
	Then	Phone-Interface-C	Set		Disconnected
	Then	ISP Usage Count		Set		0
	Do	R_SERVER.BAT		Set		Execute
	Do	ISP Usage Count		Add		1
	ENDIF
	End

Event:	TVL DL				Called ?:No
	;----------------------------------------------------------------
	; Download TV-Listings (TVLNEW.TXT) at Saturday/1AM
	;----------------------------------------------------------------
	If	TVL Enabled		Is Not		True
	Then	Event-Exit		Set		True
	;
	If	TVL Enabled		Is Now		True
	Or	Day/Time		Is Now		Saturday:1:00 AM
	Then	TVL DL Status		Set		A
	;
	;----------------------------------------------------------------
	; Initiate DL
	;----------------------------------------------------------------
	BEGINIF	TVL DL Status		Is Now		A
	If	Phone-Interface-C	Is		Operational
	Then	Phone-Interface-C	Set		Disconnected
	Then	ISP Usage Count		Set		0
	Do	TVLSTAT.TMP		Set		Delete
	Do	TVLSTAT.TMP		Set		Reset
	Do	TVL.BAT			Set		Execute/NW/ND
	Do	ISP Usage Count		Add		1
	Do	TVL DL Status		Set		A
	ENDIF
	;
	;----------------------------------------------------------------
	; Check completion-status (if active)
	;----------------------------------------------------------------
	BEGINIF	TVL DL Status		Is		A
	Do	Character-A		Set		TVLSTAT.TMP
	BEGINIF	Character-A		Is Not		None
	Do	TVL DL Status		Set		Character-A
	Do	ISP Usage Count		Subtract	1
	If	TVL DL Status		Is		D
	Then	TVL Downloaded		Set		Log
	Else	TVL Download Err	Set		Log
	ENDIF
	ENDIF
	;
	;----------------------------------------------------------------
	; Copy TVLNEW.TXT (pending listings) to TVL.TXT (active listings)
	; at Sunday/midnight.
	;----------------------------------------------------------------
	If	Day			Is Now		Sunday
	And	TVL DL Status		Is		D
	Then	COPY TVLNEW.TXT		Set		Execute
	Then	DEL TVLNEW.TXT		Set		Execute
	End
  subject (prev) or (next) | time (prev) or (next) | author (prev) or (next) | view more subjects



Services provided by [NetBloc]®! NetBloc Solutions Inc.
Terms of use. Indexing software (c) 1999 Lin-De, Inc .